home *** CD-ROM | disk | FTP | other *** search
/ PC Welt 2001 September / PC-WELT 9-2001.ISO / software / hw / brennen / flask_src.exe / idct.asm < prev    next >
Encoding:
Assembly Source File  |  2000-05-06  |  18.2 KB  |  713 lines
  1.     .586
  2.     .mmx
  3.     .model flat
  4.  
  5.     .data
  6.  
  7. ;This code is based on the fragments from the Intel Application Note AP-922.
  8. ;
  9. ;Apologies to Intel; Adobe Acrobat screws up formatting royally.
  10.  
  11. ;=============================================================================
  12. ;
  13. ; These examples contain code fragments for first stage iDCT 8x8
  14. ; (for rows) and first stage DCT 8x8 (for columns)
  15. ;
  16. ;=============================================================================
  17.  
  18. mword    typedef    qword
  19. mptr    equ    mword ptr
  20.  
  21. BITS_INV_ACC    = 4            ; 4 or 5 for IEEE
  22. SHIFT_INV_ROW    = 16 - BITS_INV_ACC
  23. SHIFT_INV_COL    = 1 + BITS_INV_ACC
  24. RND_INV_ROW    = 1024 * (6 - BITS_INV_ACC) ; 1 << (SHIFT_INV_ROW-1)
  25. RND_INV_COL    = 16 * (BITS_INV_ACC - 3) ; 1 << (SHIFT_INV_COL-1)
  26. RND_INV_CORR    = RND_INV_COL - 1 ; correction -1.0 and round
  27.  
  28.         .data
  29.         Align    16
  30.  
  31. one_corr    sword    1, 1, 1, 1
  32. round_inv_row    dword    RND_INV_ROW, RND_INV_ROW
  33. round_inv_col    sword    RND_INV_COL, RND_INV_COL, RND_INV_COL, RND_INV_COL
  34. round_inv_corr    sword    RND_INV_CORR, RND_INV_CORR, RND_INV_CORR, RND_INV_CORR
  35. tg_1_16        sword    13036, 13036, 13036, 13036    ; tg * (2<<16)
  36. tg_2_16        sword    27146, 27146, 27146, 27146    ; tg * (2<<16)
  37. tg_3_16        sword    -21746, -21746, -21746, -21746    ; tg * (2<<16) - 1.0
  38. cos_4_16    sword    -19195, -19195, -19195, -19195    ; cos * (2<<16) - 1.0
  39. ocos_4_16    sword    23170, 23170, 23170, 23170    ; cos * (2<<15) + 0.5
  40.  
  41. ;=============================================================================
  42. ;
  43. ; The first stage iDCT 8x8 - inverse DCTs of rows
  44. ;
  45. ;-----------------------------------------------------------------------------
  46. ; The 8-point inverse DCT direct algorithm
  47. ;-----------------------------------------------------------------------------
  48. ;
  49. ; static const short w[32] = {
  50. ; FIX(cos_4_16), FIX(cos_2_16), FIX(cos_4_16), FIX(cos_6_16),
  51. ; FIX(cos_4_16), FIX(cos_6_16), -FIX(cos_4_16), -FIX(cos_2_16),
  52. ; FIX(cos_4_16), -FIX(cos_6_16), -FIX(cos_4_16), FIX(cos_2_16),
  53. ; FIX(cos_4_16), -FIX(cos_2_16), FIX(cos_4_16), -FIX(cos_6_16),
  54. ; FIX(cos_1_16), FIX(cos_3_16), FIX(cos_5_16), FIX(cos_7_16),
  55. ; FIX(cos_3_16), -FIX(cos_7_16), -FIX(cos_1_16), -FIX(cos_5_16),
  56. ; FIX(cos_5_16), -FIX(cos_1_16), FIX(cos_7_16), FIX(cos_3_16),
  57. ; FIX(cos_7_16), -FIX(cos_5_16), FIX(cos_3_16), -FIX(cos_1_16) };
  58. ;
  59. ; #define DCT_8_INV_ROW(x, y)
  60. ;{
  61. ; int a0, a1, a2, a3, b0, b1, b2, b3;
  62. ;
  63. ; a0 =x[0]*w[0]+x[2]*w[1]+x[4]*w[2]+x[6]*w[3];
  64. ; a1 =x[0]*w[4]+x[2]*w[5]+x[4]*w[6]+x[6]*w[7];
  65. ; a2 = x[0] * w[ 8] + x[2] * w[ 9] + x[4] * w[10] + x[6] * w[11];
  66. ; a3 = x[0] * w[12] + x[2] * w[13] + x[4] * w[14] + x[6] * w[15];
  67. ; b0 = x[1] * w[16] + x[3] * w[17] + x[5] * w[18] + x[7] * w[19];
  68. ; b1 = x[1] * w[20] + x[3] * w[21] + x[5] * w[22] + x[7] * w[23];
  69. ; b2 = x[1] * w[24] + x[3] * w[25] + x[5] * w[26] + x[7] * w[27];
  70. ; b3 = x[1] * w[28] + x[3] * w[29] + x[5] * w[30] + x[7] * w[31];
  71. ;
  72. ; y[0] = SHIFT_ROUND ( a0 + b0 );
  73. ; y[1] = SHIFT_ROUND ( a1 + b1 );
  74. ; y[2] = SHIFT_ROUND ( a2 + b2 );
  75. ; y[3] = SHIFT_ROUND ( a3 + b3 );
  76. ; y[4] = SHIFT_ROUND ( a3 - b3 );
  77. ; y[5] = SHIFT_ROUND ( a2 - b2 );
  78. ; y[6] = SHIFT_ROUND ( a1 - b1 );
  79. ; y[7] = SHIFT_ROUND ( a0 - b0 );
  80. ;}
  81. ;
  82. ;-----------------------------------------------------------------------------
  83. ;
  84. ; In this implementation the outputs of the iDCT-1D are multiplied
  85. ; for rows 0,4 - by cos_4_16,
  86. ; for rows 1,7 - by cos_1_16,
  87. ; for rows 2,6 - by cos_2_16,
  88. ; for rows 3,5 - by cos_3_16
  89. ; and are shifted to the left for better accuracy
  90. ;
  91. ; For the constants used,
  92. ; FIX(float_const) = (short) (float_const * (1<<15) + 0.5)
  93. ;
  94. ;=============================================================================
  95.  
  96. ; Table for rows 0,4 - constants are multiplied by cos_4_16
  97.  
  98. tab_i_04    sword 16384, 16384, 16384, -16384 ; movq-> w06 w04 w02 w00
  99.         sword 21407, 8867, 8867, -21407 ; w07 w05 w03 w01
  100.         sword 16384, -16384, 16384, 16384 ; w14 w12 w10 w08
  101.         sword -8867, 21407, -21407, -8867 ; w15 w13 w11 w09
  102.         sword 22725, 12873, 19266, -22725 ; w22 w20 w18 w16
  103.         sword 19266, 4520, -4520, -12873 ; w23 w21 w19 w17
  104.         sword 12873, 4520, 4520, 19266 ; w30 w28 w26 w24
  105.         sword -22725, 19266, -12873, -22725 ; w31 w29 w27 w25
  106.  
  107. ; Table for rows 1,7 - constants are multiplied by cos_1_16
  108.  
  109. tab_i_17    sword 22725, 22725, 22725, -22725 ; movq-> w06 w04 w02 w00
  110.         sword 29692, 12299, 12299, -29692 ; w07 w05 w03 w01
  111.         sword 22725, -22725, 22725, 22725 ; w14 w12 w10 w08
  112.         sword -12299, 29692, -29692, -12299 ; w15 w13 w11 w09
  113.         sword 31521, 17855, 26722, -31521 ; w22 w20 w18 w16
  114.         sword 26722, 6270, -6270, -17855 ; w23 w21 w19 w17
  115.         sword 17855, 6270, 6270, 26722 ; w30 w28 w26 w24
  116.         sword -31521, 26722, -17855, -31521 ; w31 w29 w27 w25
  117.  
  118. ; Table for rows 2,6 - constants are multiplied by cos_2_16
  119.  
  120. tab_i_26    sword 21407, 21407, 21407, -21407 ; movq-> w06 w04 w02 w00
  121.         sword 27969, 11585, 11585, -27969 ; w07 w05 w03 w01
  122.         sword 21407, -21407, 21407, 21407 ; w14 w12 w10 w08
  123.         sword -11585, 27969, -27969, -11585 ; w15 w13 w11 w09
  124.         sword 29692, 16819, 25172, -29692 ; w22 w20 w18 w16
  125.         sword 25172, 5906, -5906, -16819 ; w23 w21 w19 w17
  126.         sword 16819, 5906, 5906, 25172 ; w30 w28 w26 w24
  127.         sword -29692, 25172, -16819, -29692 ; w31 w29 w27 w25
  128.  
  129. ; Table for rows 3,5 - constants are multiplied by cos_3_16
  130.  
  131. tab_i_35    sword 19266, 19266, 19266, -19266 ; movq-> w06 w04 w02 w00
  132.         sword 25172, 10426, 10426, -25172 ; w07 w05 w03 w01
  133.         sword 19266, -19266, 19266, 19266 ; w14 w12 w10 w08
  134.         sword -10426, 25172, -25172, -10426 ; w15 w13 w11 w09
  135.         sword 26722, 15137, 22654, -26722 ; w22 w20 w18 w16
  136.         sword 22654, 5315, -5315, -15137 ; w23 w21 w19 w17
  137.         sword 15137, 5315, 5315, 22654 ; w30 w28 w26 w24
  138.         sword -26722, 22654, -15137, -26722 ; w31 w29 w27 w25
  139.  
  140. ;-----------------------------------------------------------------------------
  141. DCT_8_INV_ROW_1 MACRO INP:REQ, OUT:REQ, TABLE:REQ
  142.  
  143.         movq        mm0, mptr [INP] ; 0 ; x3 x2 x1 x0
  144.  
  145.         movq        mm1, mptr [INP+8] ; 1 ; x7 x6 x5 x4
  146.         movq        mm2, mm0 ; 2 ; x3 x2 x1 x0
  147.  
  148.         movq        mm3, mptr [TABLE] ; 3 ; w06 w04 w02 w00
  149.         punpcklwd    mm0, mm1 ; x5 x1 x4 x0
  150.  
  151.         movq        mm5, mm0 ; 5 ; x5 x1 x4 x0
  152.         punpckldq    mm0, mm0 ; x4 x0 x4 x0
  153.  
  154.         movq        mm4, mptr [TABLE+8] ; 4 ; w07 w05 w03 w01
  155.         punpckhwd    mm2, mm1 ; 1 ; x7 x3 x6 x2
  156.  
  157.         pmaddwd        mm3, mm0 ; x4*w06+x0*w04 x4*w02+x0*w00
  158.         movq        mm6, mm2 ; 6 ; x7 x3 x6 x2
  159.  
  160.         movq        mm1, mptr [TABLE+32] ; 1 ; w22 w20 w18 w16
  161.         punpckldq    mm2, mm2 ; x6 x2 x6 x2
  162.  
  163.         pmaddwd        mm4, mm2 ; x6*w07+x2*w05 x6*w03+x2*w01
  164.         punpckhdq    mm5, mm5 ; x5 x1 x5 x1
  165.  
  166.         pmaddwd        mm0, mptr [TABLE+16] ; x4*w14+x0*w12 x4*w10+x0*w08
  167.         punpckhdq    mm6, mm6 ; x7 x3 x7 x3
  168.  
  169.         movq        mm7, mptr [TABLE+40] ; 7 ; w23 w21 w19 w17
  170.         pmaddwd        mm1, mm5 ; x5*w22+x1*w20 x5*w18+x1*w16
  171.  
  172.         paddd        mm3, mptr round_inv_row ; +rounder
  173.         pmaddwd        mm7, mm6 ; x7*w23+x3*w21 x7*w19+x3*w17
  174.  
  175.         pmaddwd        mm2, mptr [TABLE+24] ; x6*w15+x2*w13 x6*w11+x2*w09
  176.         paddd        mm3, mm4 ; 4 ; a1=sum(even1) a0=sum(even0)
  177.  
  178.         pmaddwd        mm5, mptr [TABLE+48] ; x5*w30+x1*w28 x5*w26+x1*w24
  179.         movq        mm4, mm3 ; 4 ; a1 a0
  180.  
  181.         pmaddwd        mm6, mptr [TABLE+56] ; x7*w31+x3*w29 x7*w27+x3*w25
  182.         paddd        mm1, mm7 ; 7 ; b1=sum(odd1) b0=sum(odd0)
  183.  
  184.         paddd        mm0, mptr round_inv_row ; +rounder
  185.         psubd        mm3, mm1 ; a1-b1 a0-b0
  186.  
  187.         psrad        mm3, SHIFT_INV_ROW ; y6=a1-b1 y7=a0-b0
  188.         paddd        mm1, mm4 ; 4 ; a1+b1 a0+b0
  189.  
  190.         paddd        mm0, mm2 ; 2 ; a3=sum(even3) a2=sum(even2)
  191.         psrad        mm1, SHIFT_INV_ROW ; y1=a1+b1 y0=a0+b0
  192.  
  193.         paddd        mm5, mm6 ; 6 ; b3=sum(odd3) b2=sum(odd2)
  194.         movq        mm4, mm0 ; 4 ; a3 a2
  195.  
  196.         paddd        mm0, mm5 ; a3+b3 a2+b2
  197.         psubd        mm4, mm5 ; 5 ; a3-b3 a2-b2
  198.  
  199.         psrad        mm0, SHIFT_INV_ROW ; y3=a3+b3 y2=a2+b2
  200.  
  201.         psrad        mm4, SHIFT_INV_ROW ; y4=a3-b3 y5=a2-b2
  202.  
  203.         packssdw    mm1, mm0 ; 0 ; y3 y2 y1 y0
  204.  
  205.         packssdw    mm4, mm3 ; 3 ; y6 y7 y4 y5
  206.  
  207.         movq        mm7, mm4 ; 7 ; y6 y7 y4 y5
  208.         psrld        mm4, 16 ; 0 y6 0 y4
  209.  
  210.         pslld        mm7, 16 ; y7 0 y5 0
  211.  
  212.         movq        mptr [OUT], mm1 ; 1 ; save y3 y2 y1 y0
  213.         por        mm7, mm4 ; 4 ; y7 y6 y5 y4
  214.  
  215.         movq        mptr [OUT+8], mm7 ; 7 ; save y7 y6 y5 y4
  216. ENDM
  217.  
  218.  
  219. ;=============================================================================
  220. ;
  221. ; The second stage iDCT 8x8 - inverse DCTs of columns
  222. ;
  223. ; The outputs are premultiplied
  224. ; for rows 0,4 - on cos_4_16,
  225. ; for rows 1,7 - on cos_1_16,
  226. ; for rows 2,6 - on cos_2_16,
  227. ; for rows 3,5 - on cos_3_16
  228. ; and are shifted to the left for rise of accuracy
  229. ;
  230. ;-----------------------------------------------------------------------------
  231. ;
  232. ; The 8-point scaled inverse DCT algorithm (26a8m)
  233. ;
  234. ;-----------------------------------------------------------------------------
  235. ;
  236. ;    // Reorder and prescale (implicit)
  237. ;
  238. ;    ev0 = co[0] / 2.0;
  239. ;    ev1 = co[2] / 2.0;
  240. ;    ev2 = co[4] / 2.0;
  241. ;    ev3 = co[6] / 2.0;
  242. ;    od0 = co[1] / 2.0;
  243. ;    od1 = co[3] / 2.0;
  244. ;    od2 = co[5] / 2.0;
  245. ;    od3 = co[7] / 2.0;
  246. ;
  247. ;    // 5) Apply D8T (implicit in row calculation).
  248. ;
  249. ;    tmp[0] = ev0*LAMBDA(4);
  250. ;    tmp[1] = ev2*LAMBDA(4);
  251. ;    tmp[2] = ev1*LAMBDA(2);
  252. ;    tmp[3] = ev3*LAMBDA(2);
  253. ;    tmp[4] = od0*LAMBDA(1);
  254. ;    tmp[5] = od3*LAMBDA(1);
  255. ;    tmp[6] = od1*LAMBDA(3);
  256. ;    tmp[7] = od2*LAMBDA(3);
  257. ;
  258. ;    // 4) Apply B8T.
  259. ;
  260. ;    double x0, x1, x2, x3, y0, y1, y2, y3;
  261. ;
  262. ;    x0 = tmp[0] + tmp[1];
  263. ;    x1 = tmp[0] - tmp[1];
  264. ;    x2 = tmp[2] + TAN(2)*tmp[3];
  265. ;    x3 = tmp[2]*TAN(2) - tmp[3];
  266. ;    y0 = tmp[4] + TAN(1)*tmp[5];
  267. ;    y1 = tmp[4]*TAN(1) - tmp[5];
  268. ;    y2 = tmp[6] + TAN(3)*tmp[7];
  269. ;    y3 = tmp[6]*TAN(3) - tmp[7];
  270. ;
  271. ;    // 3) Apply E8T.
  272. ;    //
  273. ;    //    1  0  1  0
  274. ;    //    0  1  0  1
  275. ;    //    0  1  0 -1
  276. ;    //    1  0 -1  0
  277. ;    //            1  0  1  0
  278. ;    //            1  0 -1  0
  279. ;    //            0  1  0  1
  280. ;    //            0  1  0 -1
  281. ;
  282. ;    double e0, e1, e2, e3, o0, o1, o2, o3;
  283. ;
  284. ;    e0 = x0 + x2;
  285. ;    e1 = x1 + x3;
  286. ;    e2 = x1 - x3;
  287. ;    e3 = x0 - x2;
  288. ;    o0 = y0 + y2;
  289. ;    o1 = y0 - y2;
  290. ;    o2 = y1 + y3;
  291. ;    o3 = y1 - y3;
  292. ;
  293. ;    // 2) Apply F8T.
  294. ;
  295. ;    double a, b;
  296. ;
  297. ;    a = (o1 + o2) * LAMBDA(4);
  298. ;    b = (o1 - o2) * LAMBDA(4);
  299. ;
  300. ;    o1 = a;
  301. ;    o2 = b;
  302. ;
  303. ;    // 6) Apply output butterfly (A8T).
  304. ;    //
  305. ;    // 1 0 0 0  1  0  0  0
  306. ;    // 0 1 0 0  0  1  0  0
  307. ;    // 0 0 1 0  0  0  1  0
  308. ;    // 0 0 0 1  0  0  0  1
  309. ;    // 0 0 0 1  0  0  0 -1
  310. ;    // 0 0 1 0  0  0 -1  0
  311. ;    // 0 1 0 0  0 -1  0  0
  312. ;    // 1 0 0 0 -1  0  0  0
  313. ;
  314. ;    out[0] = e0 + o0;
  315. ;    out[1] = e1 + o1;
  316. ;    out[2] = e2 + o2;
  317. ;    out[3] = e3 + o3;
  318. ;    out[4] = e3 - o3;
  319. ;    out[5] = e2 - o2;
  320. ;    out[6] = e1 - o1;
  321. ;    out[7] = e0 - o0;
  322. ;
  323. ;=============================================================================
  324. DCT_8_INV_COL_4 MACRO INP:REQ, OUT:REQ
  325. LOCAL    x0, x1, x2, x3, x4, x5, x6, x7
  326. LOCAL    y0, y1, y2, y3, y4, y5, y6, y7
  327.  
  328. x0    equ    [INP + 0*16]
  329. x1    equ    [INP + 1*16]
  330. x2    equ    [INP + 2*16]
  331. x3    equ    [INP + 3*16]
  332. x4    equ    [INP + 4*16]
  333. x5    equ    [INP + 5*16]
  334. x6    equ    [INP + 6*16]
  335. x7    equ    [INP + 7*16]
  336. y0    equ    [OUT + 0*16]
  337. y1    equ    [OUT + 1*16]
  338. y2    equ    [OUT + 2*16]
  339. y3    equ    [OUT + 3*16]
  340. y4    equ    [OUT + 4*16]
  341. y5    equ    [OUT + 5*16]
  342. y6    equ    [OUT + 6*16]
  343. y7    equ    [OUT + 7*16]
  344.  
  345.     ;======= optimized code
  346.  
  347.     IF 1
  348.  
  349.     ;ODD ELEMENTS
  350.  
  351.     movq    mm0,x1        ;tmp[4]
  352.  
  353.     movq    mm1,x7        ;tmp[5]
  354.     movq    mm4,mm0
  355.  
  356.     movq    mm2,x3        ;tmp[6]
  357.     movq    mm5,mm1
  358.  
  359.     movq    mm3,x5        ;tmp[7]
  360.     movq    mm6,mm2
  361.  
  362.     pmulhw    mm6,qword ptr tg_3_16    ;tmp[6]*(tan(3pi/16) - 0.5)
  363.     movq    mm7,mm3
  364.  
  365.     pmulhw    mm7,qword ptr tg_3_16    ;tmp[7]*(tan(3pi/16) - 0.5)
  366.     ;v
  367.  
  368.     pmulhw    mm5,qword ptr tg_1_16    ;tmp[5]*tan(1pi/16)
  369.     ;v
  370.  
  371.     pmulhw    mm4,qword ptr tg_1_16    ;tmp[4]*tan(1pi/16)
  372.     paddw    mm6,mm2        ;tmp[6]*tan(3pi/16)
  373.  
  374.     psubw    mm6,mm3        ;mm6 = y3 = tmp[6]*TAN(3) - tmp[7]
  375.     paddw    mm7,mm3        ;tmp[7]*tan(3pi/16)
  376.  
  377.     paddw    mm5,mword ptr one_corr
  378.     paddw    mm2,mm7        ;mm2 = y2 = tmp[6] + TAN(3)*tmp[7]
  379.  
  380.     paddw    mm0,mm5        ;mm0 = y0 = tmp[4] + TAN(1)*tmp[5]
  381.     psubw    mm4,mm1        ;mm4 = y1 = tmp[4]*TAN(1) - tmp[5]
  382.  
  383.     ;E8T butterfly - odd elements
  384.  
  385.     movq    mm1,mm0
  386.     movq    mm5,mm4
  387.     paddw    mm0,mm2        ;mm0 = o0 = y0 + y2
  388.     psubw    mm1,mm2        ;mm1 = o1 = y0 - y2
  389.     paddw    mm4,mm6        ;mm4 = o2 = y1 + y3
  390.     psubw    mm5,mm6        ;mm5 = o3 = y1 - y3
  391.  
  392.     ;F8T stage - odd elements
  393.  
  394.     movq    mm2,mm1
  395.     paddw    mm1,mm4        ;mm1 = o1 + o2
  396.  
  397.     psubw    mm2,mm4        ;mm2 = o1 - o2
  398.     movq    mm6,mm1
  399.  
  400.     pmulhw    mm1,qword ptr cos_4_16
  401.     movq    mm7,mm2
  402.  
  403.     pmulhw    mm2,qword ptr cos_4_16
  404.  
  405.     por    mm1,mword ptr one_corr
  406.  
  407.     psubw    mm2,mword ptr one_corr
  408.  
  409.     paddw    mm1,mm6        ;mm1 = o1' = (o1 + o2)*LAMBDA(4)
  410.     paddw    mm2,mm7        ;mm2 = o2' = (o1 - o2)*LAMBDA(4)
  411.  
  412.     ;HOLD these registers:
  413.     ;
  414.     ;    mm0 = o0
  415.     ;    mm1 = o1
  416.     ;    mm2 = o2
  417.     ;    mm5 = o3
  418.  
  419.     ;EVEN ELEMENTS
  420.  
  421.     ;B8T stage - first two even elements
  422.  
  423.     movq    mm3,x0        ;mm3 = tmp[0]
  424.     movq    mm4,mm3
  425.     paddw    mm3,x4        ;mm3 = x0 = tmp[0] + tmp[1]
  426.     psubw    mm4,x4        ;mm4 = x1 = tmp[0] - tmp[1]
  427.     
  428.     ;B8T stage - x2 element
  429.  
  430.     movq    mm7,x6        ;mm7 = tmp[3]
  431.     pmulhw    mm7,qword ptr tg_2_16    ;mm7 = tmp[3] * TAN(2)
  432.  
  433.     paddw    mm7,mword ptr one_corr
  434.  
  435.     paddw    mm7,x2        ;mm7 = x2 = tmp[2] + tmp[3]*TAN(2)
  436.  
  437.     ;E8T stage - x0 and x2 elements
  438.  
  439.     movq    mm6,mm3
  440.     paddw    mm3,mm7        ;mm3 = e0 = x0+x2
  441.     psubw    mm6,mm7        ;mm6 = e3 = x0-x2
  442.  
  443.     ;output butterfly - 0 and 3
  444.  
  445.     movq    mm7,mm3        ;mm7 = e0
  446.     paddw    mm3,mm0        ;mm3 = e0 + o0
  447.     psubw    mm7,mm0        ;mm7 = e0 - o0
  448.     paddw    mm3,qword ptr round_inv_corr
  449.     paddw    mm7,qword ptr round_inv_corr
  450.  
  451.     psraw    mm3,SHIFT_INV_COL
  452.     psraw    mm7,SHIFT_INV_COL
  453.     movq    y0,mm3
  454.     movq    y7,mm7
  455.  
  456.     movq    mm7,mm6        ;mm7 = e3 
  457.     paddw    mm6,mm5        ;mm6 = e3 + o3
  458.     psubw    mm7,mm5        ;mm7 = e3 - o3
  459.     paddw    mm6,qword ptr round_inv_col
  460.     paddw    mm7,qword ptr round_inv_col
  461.  
  462.     psraw    mm6,SHIFT_INV_COL
  463.     psraw    mm7,SHIFT_INV_COL
  464.     movq    y3,mm6
  465.     movq    y4,mm7
  466.  
  467.     ;B8T stage - x3 element
  468.  
  469.     movq    mm6,x2        ;mm6 = tmp[2]
  470.     pmulhw    mm6,qword ptr tg_2_16    ;mm6 = tmp[2] * TAN(2)
  471.  
  472.     paddw    mm6,mword ptr one_corr
  473.  
  474.     psubw    mm6,x6        ;mm6 = x3 = tmp[2]*TAN(2) - tmp[3]
  475.  
  476.     ;E8T stage - x1 and x3 elements
  477.  
  478.     movq    mm7,mm4
  479.     paddw    mm4,mm6        ;mm4 = e1 = x1+x3
  480.     psubw    mm7,mm6        ;mm7 = e2 = x1-x3
  481.  
  482.     ;output butterfly - 1 and 2
  483.  
  484.     movq    mm6,mm4                ;mm6 = e1
  485.     paddw    mm4,mm1                ;mm4 = e1 + o1
  486.     psubw    mm6,mm1                ;mm4 = e1 - o1
  487.     paddw    mm4,qword ptr round_inv_corr
  488.     paddw    mm6,qword ptr round_inv_corr
  489.  
  490.     psraw    mm4,SHIFT_INV_COL
  491.     psraw    mm6,SHIFT_INV_COL
  492.     movq    y1,mm4
  493.     movq    y6,mm6
  494.  
  495.     movq    mm6,mm7                ;mm6 = e2
  496.     paddw    mm7,mm2                ;mm7 = e2 + o2
  497.     psubw    mm6,mm2                ;mm6 = e2 - o2
  498.     paddw    mm7,qword ptr round_inv_col
  499.     paddw    mm6,qword ptr round_inv_col
  500.  
  501.     psraw    mm7,SHIFT_INV_COL
  502.     psraw    mm6,SHIFT_INV_COL
  503.     movq    y2,mm7
  504.     movq    y5,mm6
  505.  
  506.     ;======= unoptimized code
  507.  
  508.     ELSE
  509.     movq    mm0,x1        ;tmp[4]
  510.     movq    mm1,x7        ;tmp[5]
  511.     movq    mm2,x3        ;tmp[6]
  512.     movq    mm3,x5        ;tmp[7]
  513.  
  514.     movq    mm4,mm0
  515.     movq    mm5,mm1
  516.     movq    mm6,mm2
  517.     movq    mm7,mm3
  518.     pmulhw    mm4,qword ptr tg_1_16    ;tmp[4]*tan(1pi/16)
  519.     pmulhw    mm5,qword ptr tg_1_16    ;tmp[5]*tan(1pi/16)
  520.     pmulhw    mm6,qword ptr tg_3_16    ;tmp[6]*(tan(3pi/16) - 0.5)
  521.     pmulhw    mm7,qword ptr tg_3_16    ;tmp[7]*(tan(3pi/16) - 0.5)
  522.  
  523.     paddw    mm5,mword ptr one_corr
  524.  
  525.     paddw    mm6,mm2        ;tmp[6]*tan(3pi/16)
  526.     paddw    mm7,mm3        ;tmp[7]*tan(3pi/16)
  527.     paddw    mm0,mm5        ;mm0 = y0 = tmp[4] + TAN(1)*tmp[5]
  528.     psubw    mm4,mm1        ;mm4 = y1 = tmp[4]*TAN(1) - tmp[5]
  529.     paddw    mm2,mm7        ;mm2 = y2 = tmp[6] + TAN(3)*tmp[7]
  530.     psubw    mm6,mm3        ;mm6 = y3 = tmp[6]*TAN(3) - tmp[7]
  531.  
  532.     ;E8T butterfly - odd elements
  533.  
  534.     movq    mm1,mm0
  535.     movq    mm5,mm4
  536.     paddw    mm0,mm2        ;mm0 = o0 = y0 + y2
  537.     psubw    mm1,mm2        ;mm1 = o1 = y0 - y2
  538.     paddw    mm4,mm6        ;mm4 = o2 = y1 + y3
  539.     psubw    mm5,mm6        ;mm5 = o3 = y1 - y3
  540.  
  541.     ;F8T stage - odd elements
  542.  
  543.     movq    mm2,mm1
  544.     paddw    mm1,mm4        ;mm1 = o1 + o2
  545.     psubw    mm2,mm4        ;mm2 = o1 - o2
  546.     movq    mm6,mm1
  547.     movq    mm7,mm2
  548.     pmulhw    mm1,qword ptr cos_4_16
  549.     pmulhw    mm2,qword ptr cos_4_16
  550.  
  551.     por    mm1,mword ptr one_corr
  552.     psubw    mm2,mword ptr one_corr
  553.  
  554.     paddw    mm1,mm6        ;mm1 = o1' = (o1 + o2)*LAMBDA(4)
  555.     paddw    mm2,mm7        ;mm2 = o2' = (o1 - o2)*LAMBDA(4)
  556.  
  557.     ;HOLD these registers:
  558.     ;
  559.     ;    mm0 = o0
  560.     ;    mm1 = o1
  561.     ;    mm2 = o2
  562.     ;    mm5 = o3
  563.  
  564.     ;EVEN ELEMENTS
  565.  
  566.     ;B8T stage - first two even elements
  567.  
  568.     movq    mm3,x0        ;mm3 = tmp[0]
  569.     movq    mm4,mm3
  570.     paddw    mm3,x4        ;mm3 = x0 = tmp[0] + tmp[1]
  571.     psubw    mm4,x4        ;mm4 = x1 = tmp[0] - tmp[1]
  572.     
  573.     ;B8T stage - x2 element
  574.  
  575.     movq    mm7,x6        ;mm7 = tmp[3]
  576.     pmulhw    mm7,qword ptr tg_2_16    ;mm7 = tmp[3] * TAN(2)
  577.  
  578.     paddw    mm7,mword ptr one_corr
  579.  
  580.     paddw    mm7,x2        ;mm7 = x2 = tmp[2] + tmp[3]*TAN(2)
  581.  
  582.     ;E8T stage - x0 and x2 elements
  583.  
  584.     movq    mm6,mm3
  585.     paddw    mm3,mm7        ;mm3 = e0 = x0+x2
  586.     psubw    mm6,mm7        ;mm6 = e3 = x0-x2
  587.  
  588.     ;output butterfly - 0 and 3
  589.  
  590.     movq    mm7,mm3        ;mm7 = e0
  591.     paddw    mm3,mm0        ;mm3 = e0 + o0
  592.     psubw    mm7,mm0        ;mm7 = e0 - o0
  593.     paddw    mm3,qword ptr round_inv_corr
  594.     paddw    mm7,qword ptr round_inv_corr
  595.  
  596.     psraw    mm3,SHIFT_INV_COL
  597.     psraw    mm7,SHIFT_INV_COL
  598.     movq    y0,mm3
  599.     movq    y7,mm7
  600.  
  601.     movq    mm7,mm6        ;mm7 = e3 
  602.     paddw    mm6,mm5        ;mm6 = e3 + o3
  603.     psubw    mm7,mm5        ;mm7 = e3 - o3
  604.     paddw    mm6,qword ptr round_inv_col
  605.     paddw    mm7,qword ptr round_inv_col
  606.  
  607.     psraw    mm6,SHIFT_INV_COL
  608.     psraw    mm7,SHIFT_INV_COL
  609.     movq    y3,mm6
  610.     movq    y4,mm7
  611.  
  612.     ;B8T stage - x3 element
  613.  
  614.     movq    mm6,x2        ;mm6 = tmp[2]
  615.     pmulhw    mm6,qword ptr tg_2_16    ;mm6 = tmp[2] * TAN(2)
  616.  
  617.     paddw    mm6,mword ptr one_corr
  618.  
  619.     psubw    mm6,x6        ;mm6 = x3 = tmp[2]*TAN(2) - tmp[3]
  620.  
  621.     ;E8T stage - x1 and x3 elements
  622.  
  623.     movq    mm7,mm4
  624.     paddw    mm4,mm6        ;mm4 = e1 = x1+x3
  625.     psubw    mm7,mm6        ;mm7 = e2 = x1-x3
  626.  
  627.     ;output butterfly - 1 and 2
  628.  
  629.     movq    mm6,mm4                ;mm6 = e1
  630.     paddw    mm4,mm1                ;mm4 = e1 + o1
  631.     psubw    mm6,mm1                ;mm4 = e1 - o1
  632.     paddw    mm4,qword ptr round_inv_corr
  633.     paddw    mm6,qword ptr round_inv_corr
  634.  
  635.     psraw    mm4,SHIFT_INV_COL
  636.     psraw    mm6,SHIFT_INV_COL
  637.     movq    y1,mm4
  638.     movq    y6,mm6
  639.  
  640.     movq    mm6,mm7                ;mm6 = e2
  641.     paddw    mm7,mm2                ;mm7 = e2 + o2
  642.     psubw    mm6,mm2                ;mm6 = e2 - o2
  643.     paddw    mm7,qword ptr round_inv_col
  644.     paddw    mm6,qword ptr round_inv_col
  645.  
  646.     psraw    mm7,SHIFT_INV_COL
  647.     psraw    mm6,SHIFT_INV_COL
  648.     movq    y2,mm7
  649.     movq    y5,mm6
  650.  
  651.     ENDIF
  652. ENDM
  653.  
  654.     .code
  655.  
  656.     public _IDCT_mmx
  657.  
  658. _IDCT_mmx:
  659.     mov    edx,esp
  660.     sub    esp,256
  661.     and    esp,0fffffff8h
  662.  
  663.     mov    eax,[edx+4]
  664.  
  665.     DCT_8_INV_ROW_1        eax+0*16, esp+0*16, tab_i_04
  666.     DCT_8_INV_ROW_1        eax+1*16, esp+1*16, tab_i_17
  667.     DCT_8_INV_ROW_1        eax+2*16, esp+2*16, tab_i_26
  668.     DCT_8_INV_ROW_1        eax+3*16, esp+3*16, tab_i_35
  669.     DCT_8_INV_ROW_1        eax+4*16, esp+4*16, tab_i_04
  670.     DCT_8_INV_ROW_1        eax+5*16, esp+5*16, tab_i_35
  671.     DCT_8_INV_ROW_1        eax+6*16, esp+6*16, tab_i_26
  672.     DCT_8_INV_ROW_1        eax+7*16, esp+7*16, tab_i_17
  673.     DCT_8_INV_COL_4        esp+0, esp+8*16
  674.     DCT_8_INV_COL_4        esp+8, esp+8*16+8
  675.  
  676.     mov    ecx,[edx+8]
  677.     test    dword ptr [edx+16],-1
  678.     jz        inter_start
  679.  
  680.     mov        eax,-8*16
  681. intra_loop:
  682.     movq        mm0,[esp+eax+16*16]
  683.     movq        mm1,[esp+eax+16*16+8]
  684.     packuswb    mm0,mm1
  685.     movq        [ecx],mm0
  686.     add        ecx,[edx+12]
  687.     add        eax,16
  688.     jne        intra_loop
  689.     mov    esp,edx
  690.     ret
  691.  
  692. inter_start:
  693.     mov        eax,-8*16
  694.     pxor        mm7,mm7
  695. inter_loop:
  696.     movq        mm0,[esp+eax+16*16]
  697.     movq        mm1,[esp+eax+16*16+8]
  698.     movq        mm2,[ecx]
  699.     movq        mm3,mm2
  700.     punpcklbw    mm2,mm7
  701.     punpckhbw    mm3,mm7
  702.     paddw        mm0,mm2
  703.     paddw        mm1,mm3
  704.     packuswb    mm0,mm1
  705.     movq        [ecx],mm0
  706.     add        ecx,[edx+12]
  707.     add        eax,16
  708.     jne        inter_loop
  709.     mov    esp,edx
  710.     ret
  711.  
  712.     end
  713.